<cheat>
   <name>Backlight control</name>
   <note>Hold L+R+SELECT then press UP to increase brightness or DOWN to decrease brightness</note>
   <codes>94000130 FCFB0000 C2000001 000000a0 a21ab5f0 88234c24 80138811 d02a428b 25803490 f0002000 1c06f82a f0002004 2703f826 21404007 d003420b 420b2180 e018d00c 4231210c 2f03d006 1c79d013 f0002004 e00ef816 e0094331 438e210c 2f001c31 1e79d004 f0002004 e002f80a f0002000 bcf0f806 4718bc08 30800000 88222100 d1fc422a 80224a08 88208060 d1fc4228 80220c12 88228061 d1fc422a 21ff8860 47704008 04000130 80028802 d2000000 00000000 </codes>
</cheat>

.thumb

@ all of the following are 16 bit
.equ   REG_SPICNT,  0x040001C0
.equ   REG_SPIDATA,    0x040001C2
.equ   REG_KEYINPUT,   0x04000130

.equ   KEYS_L_R_SELECT, ((1<<9) | (1<<8) | (1<<2))
.equ   KEYS_UP,   (1<<6)
.equ   KEYS_DOWN,   (1<<7)

.equ   PM_CONTROL_REG, 0
.equ   PM_LITE_BRIGHT_REG, 4
.equ   PM_BACKLIGHTS, ((1<<2) | (1<<3))
.equ   SPI_BUSY, 0x80


cheat_header:
   .word   0x94000130, ((~KEYS_L_R_SELECT & 0xFFFF) << 16)   @ Button activator
   .word   0xC2000001, (brightnessHandler_end - brightnessHandler)   @ Execute custom function in thumb mode

brightnessHandler:
   push   {r4-r7, lr}
   
   adr   r2, old_key_state
   ldr   r4, =REG_KEYINPUT
   ldrh   r3, [r4]   @ Current key state
   ldrh    r1, [r2]   @ Old key state
   strh   r3,   [r2]   @ Save current key state for next time
   cmp      r3, r1      @ if keys in same state as before
   beq   brightnessHandler_exit

   @ must be done before calling readPowerMangement or writePowerManagement
   add      r4, #(REG_SPICNT - REG_KEYINPUT)
   mov      r5, #SPI_BUSY

   @ Old power management setting
   mov   r0, #PM_CONTROL_REG
   bl   readPowerMangement
   mov   r6, r0      @ r6 = old power management setting

   @ Old backlight level setting
   mov   r0, #PM_LITE_BRIGHT_REG
   bl   readPowerMangement
   mov   r7, #0x03
   and   r7, r0      @ r7 = old backlight level setting

   mov   r1, #KEYS_UP
   tst   r3, r1
   beq   brightnessHandler_keyUp
   mov   r1, #KEYS_DOWN
   tst   r3, r1
   beq   brightnessHandler_keyDown
   b   brightnessHandler_exit
   
brightnessHandler_keyUp:
   @ enable backlights if off
   mov   r1, #PM_BACKLIGHTS
   tst   r1,   r6
   beq   brightnessHandler_turnOnScreens

   @ increase brightness
   cmp      r7, #0x03
   beq      brightnessHandler_exit
   add      r1, r7, #1
   
   mov   r0, #PM_LITE_BRIGHT_REG
   bl   writePowerManagement
   b   brightnessHandler_exit

brightnessHandler_turnOnScreens:
   @ enable backlights
   orr   r1,   r6
   b   brightnessHandler_setScreenStatus
   
brightnessHandler_keyDown:
   @ get ready to disable backlights if needed
   mov   r1, #PM_BACKLIGHTS
   bic   r6, r1
   mov   r1, r6
   @ turn off screens if already on lowest level
   cmp      r7, #0x00
   beq      brightnessHandler_setScreenStatus
   
   @ reduce brightness
   sub      r1, r7, #1
   mov   r0, #PM_LITE_BRIGHT_REG
   bl   writePowerManagement
   b   brightnessHandler_exit

brightnessHandler_setScreenStatus:
   @ set new power management control
   mov   r0, #PM_CONTROL_REG
   bl   writePowerManagement
      
brightnessHandler_exit:
   pop      {r4-r7}
   pop   {r3}
   bx   r3
   
old_key_state:
   .hword 0x0000
   
readPowerMangement:
   add      r0, #(1<<7)
   mov      r1, #0
   @ fall through to _writePowerManagement


writePowerManagement:   @ (reg, command)
   
   @ while (REG_SPICNT & SPI_BUSY);
writePowerManagement_loop1:
   ldrh   r2, [r4]
   tst      r2, r5
   bne      writePowerManagement_loop1
   
   @ REG_SPICNT = SPI_ENABLE | SPI_BAUD_1MHZ | SPI_BYTE_MODE | SPI_CONTINUOUS | SPI_DEVICE_POWER;
   ldr      r2, =((1<<15) | 2 | (0<<10) | (1<<11) | (0<<8)) | (((1<<15) | 2 | (0<<10) | (0<<8)) << 16)
   strh   r2, [r4]
   
   @ REG_SPIDATA = reg;
   strh      r0, [r4, #2]
   
   @ while (REG_SPICNT & SPI_BUSY);
writePowerManagement_loop2:
   ldrh   r0, [r4]
   tst      r0, r5
   bne      writePowerManagement_loop2
   
   @ REG_SPICNT = SPI_ENABLE | SPI_BAUD_1MHZ | SPI_BYTE_MODE | SPI_DEVICE_POWER;
   lsr      r2, #16
   strh   r2, [r4]
   
   @ REG_SPIDATA = command;
   strh   r1, [r4, #2]
   
   @ while (REG_SPICNT & SPI_BUSY);
writePowerManagement_loop3:
   ldrh   r2, [r4]
   tst      r2, r5
   bne      writePowerManagement_loop3
   
   @ return REG_SPIDATA & 0xFF;
   ldrh   r0, [r4, #2]
   mov      r1, #0xff
   and      r0, r1
   bx       lr

constant_pool:
.pool

.align 3
brightnessHandler_end:

cheat_footer:
   .word   0xd2000000,   0x00000000   @ End if

include $(DEVKITARM)/ds_rules

brightness.cht   :   brightness.bin
   @od -A n -t x4 -w8 $< > $@
   @echo Raw cheat codes written to $@

brightness.bin   :   brightness.o
   $(OBJCOPY) -O binary $< $@

brightness.o   :   brightness.s

<cheat>
   <name>Backlight control</name>
   <note>Hold L+R+SELECT then press UP to increase brightness or DOWN to decrease brightness</note>
   <codes>94000130 FCFB0000 023FE074 012FFF11 E0000000 000000A8 E28F0001 E12FFF10 A21AB5F0 88234C24  80138811 d02a428b 25803490 f0002000 1c06f82a f0002004 2703f826 21404007 d003420b 420b2180 e018d00c 4231210c 2f03d006 1c79d013 f0002004 e00ef816 e0094331 438e210c 2f001c31 1e79d004 f0002004 e002f80a f0002000 bcf0f806 4718bc08 30800000 88222100 d1fc422a 80224a08 88208060 d1fc4228 80220c12 88228061 d1fc422a 21ff8860 47704008 04000130 80028802 023FE074 E3520003 d2000000 00000000 </codes>
</cheat>

<cheat>
   <name>Backlight control (Phat)</name>
   <note>Hold L+R+SELECT then press UP to turn on screens or DOWN to turn off screens</note>
   <codes>94000130 fcfb0000 c2000001 00000080 a21cb5f0 88234c1c 80138811 d019428b 25803490 f0002000 1c06f818 420b2140 2180d003 d005420b 210ce00c d1094231 e0044331 4231210c 438ed004 20001c31 f805f000 bc08bcf0 30804718 88222100 d1fc422a 80224a09 88208060 d1fc4228 80220c12 88228061 d1fc422a 21ff8860 47704008 00000000 04000130 80028802 d2000000 00000000 </codes>
</cheat>