; Silent Hill "Inventory Editor"
; Copyright 2001-2007 Parasyte
;
; Project began 10-10-2001, completed 04-15-2007
;
; 800AE17C - Cursor position modifier
; 8004CC2C - Cursor position modifier read breakpoint (breakout location)
; 800BCA34 - Slot 1 modifier
; 800BC76C - Pad value
; 800BC774 - Down-state pad value (not used)

.org    0x80007800
lw      $v0, 0xE17C($v1)        ; Moved from break out location [read current cursor position]
lw      $a2, 0x0000($zero)      ; Counter = byte at (80000000)
bgez    $a2, return             ; If counter == 0, continue (and decrement counter)
addiu   $a2, $a2, 0xFFFF        ; Decrement counter

begin:
lhu     $t1, 0xC76C($s4)        ; load pad value into $t1
ori     $s1, $s3, 0xCA34        ; $s1 = 800BCA34 (slot 1 mod)
sll     $v1, $v0, 0x0002        ; $at = Current cursor position * 4
addu    $s1, $s1, $v1           ; $s1 = Current slot selected
lbu     $v1, 0x0000($s1)        ; Load item number (from current slot) into $v1
lbu     $s0, 0x0001($s1)        ; Load quantity of current slot into $a0
addu    $a3, $v1, $zero         ; Copy item number to a backup register

andi    $t8, $t1, 0x0800        ; Check for R1
beq     $t8, $zero, notR1       ; If R1 is not pushed, branch (and check for L1)
andi    $t8, $t1, 0x0400        ; Check for L1
addiu   $a3, $v1, 0x0001        ; Increment item in current slot

notR1:
beq     $t8, $zero, notL1       ; If L1 is not pushed, branch (and check for R2)
andi    $t8, $t1, 0x0200        ; Check for R2
addiu   $a3, $v1, 0xFFFF        ; Decrement item in current slot

notL1:
beq     $t8, $zero, notR2       ; If R2 is not pushed, branch (and check for L2)
andi    $t8, $t1, 0x0100        ; Check for L2
addiu   $s0, $s0, 0x0001        ; Increment item value in current slot
ori     $a2, $zero, 0x0009      ; Counter = 9

notR2:
beq     $t8, $zero, notL2       ; If L2 is not pushed, branch
nop
addiu   $s0, $s0, 0xFFFF        ; Decrement item value in current slot
ori     $a2, $zero, 0x0009      ; Counter = 9

notL2:
beq     $a3, $v1, no_new_item   ; Update item only when changed

; Here is where some magic happens by clipping the item into the valid ranges
slt     $v1, $v1, $a3           ; $v1 = 1 if we are increasing, or 0 if decreasing
sll     $t6, $v1, 0x0001
addiu   $t6, $t6, 0xFFFF        ; $t6 = 1 if we are increasing, or -1 if decreasing
addu    $at, $t6, $v1           ; $at = 2 if we are increasing, or -1 if decreasing
addiu   $t7, $zero, 0x000A      ; Number of lines in the lookup table

loop:
lbu     $t8, 0x7901($v1)        ; Check item against lookup table (this instruction is non-relocatable)
addu    $t8, $t8, $t6
bne     $t8, $a3, valid_item
addiu   $t7, $t7, 0xFFFF
lbu     $a3, 0x7901($at)        ; Load proper item (this instruction is non-relocatable)

valid_item:
addiu   $v1, $v1, 0x0002
bgtz    $t7, loop
addiu   $at, $at, 0x0002

jal     0x80054200              ; Update screen (redraw items)
sb      $a3, 0x0000($s1)        ; Update item in current slot
ori     $a2, $zero, 0x0009      ; Counter = 9
no_new_item:
sb      $s0, 0x0001($s1)        ; Update item value in current slot

return:
j       0x0004CC34              ; Return to breakout location
sw      $a2, 0x0000($zero)      ; Store counter into 80000000


.org    0x80007900
.db           0xFF
.db     0x20, 0x22              ; Every two bytes defines a range of "valid" items
.db     0x40, 0x55
.db     0x57, 0x58
.db     0x60, 0x6E
.db     0x70, 0x82
.db     0x84, 0x87
.db     0xA0, 0xA3
.db     0xC0, 0xC2
.db     0xE0, 0xE2
.db     0xFF, 0xFF
.db     0x20


.org    0x8004CC2C
j       0x80007800